FM / vendor-completions

/usr/share/zsh/vendor-completions

Name	Size	Mode	Actions
_bootctl	2063	0644	edit dl rm
_busctl	9626	0644	edit dl rm
_curl	14150	0644	edit dl rm
_docker	7748	0644	edit dl rm
_hostnamectl	2598	0644	edit dl rm
_journalctl	6845	0644	edit dl rm
_kernel-install	811	0644	edit dl rm
_localectl	3805	0644	edit dl rm
_loginctl	6244	0644	edit dl rm
_networkctl	1417	0644	edit dl rm
_resolvectl	3900	0644	edit dl rm
_sd_hosts_or_user_at_host	120	0644	edit dl rm
_sd_outputmodes	298	0644	edit dl rm
_sd_unit_files	255	0644	edit dl rm
_snap	1792	0644	edit dl rm
_systemctl	18898	0644	edit dl rm
_systemd	3880	0644	edit dl rm
_systemd-analyze	3565	0644	edit dl rm
_systemd-delta	665	0644	edit dl rm
_systemd-inhibit	1211	0644	edit dl rm
_systemd-run	3326	0644	edit dl rm
_systemd-tmpfiles	776	0644	edit dl rm
_timedatectl	2082	0644	edit dl rm
_udevadm	6386	0644	edit dl rm

Edit: /usr/share/zsh/vendor-completions/_systemd-analyze (3565B)

#compdef systemd-analyze                    -*- shell-script -*-
# SPDX-License-Identifier: LGPL-2.1+

(( $+functions[_systemd-analyze_log-level] )) ||
    _systemd-analyze_log-level() {
        local -a _levels
        _levels=(debug info notice warning err crit alert emerg)
        _describe -t level 'logging level' _levels || compadd "$@"
    }

(( $+functions[_systemd-analyze_log-target] )) ||
    _systemd-analyze_log-target() {
        local -a _targets
        _targets=(console journal kmsg journal-or-kmsg null)
        _describe -t target 'logging target' _targets || compadd "$@"
    }

(( $+functions[_systemd-analyze_verify] )) ||
    _systemd-analyze_verify() {
        _sd_unit_files
    }

(( $+functions[_systemd-analyze_service-watchdogs] )) ||
    _systemd-analyze_service-watchdogs() {
        local -a _states
        _states=(on off)
        _describe -t state 'state' _states || compadd "$@"
    }

(( $+functions[_systemd-analyze_commands] )) ||
    _systemd-analyze_commands(){
        local -a _systemd_analyze_cmds
        # Descriptions taken from systemd-analyze --help.
        _systemd_analyze_cmds=(
            'time:Print time spent in the kernel before reaching userspace'
            'blame:Print list of running units ordered by time to init'
            'critical-chain:Print a tree of the time critical chain of units'
            'plot:Output SVG graphic showing service initialization'
            'dot:Dump dependency graph (in dot(1) format)'
            'dump:Dump server status'
            'unit-paths:List unit load paths'
            'log-level:Get/set systemd log threshold'
            'log-target:Get/set systemd log target'
            'service-watchdogs:Get/set service watchdog status'
            'syscall-filter:List syscalls in seccomp filter'
            'verify:Check unit files for correctness'
            'calendar:Validate repetitive calendar time events'
        )

if (( CURRENT == 1 )); then
            _describe "options" _systemd_analyze_cmds
        else
            local curcontext="$curcontext"
            cmd="${${_systemd_analyze_cmds[(r)$words[1]:*]%%:*}}"
            if (( $#cmd )); then
                if (( $+functions[_systemd-analyze_$cmd] )) && (( CURRENT == 2 )); then
                    _systemd-analyze_$cmd
                else
                    _message "no more options"
                fi
            else
                _message "unknown systemd-analyze command: $words[1]"
            fi
        fi
    }

_arguments \
    {-h,--help}'[Show help text]' \
    '--version[Show package version]' \
    '--system[Operate on system systemd instance]' \
    '--user[Operate on user systemd instance]' \
    '--global[Show global user instance config]' \
    '--no-pager[Do not pipe output into a pager]' \
    '--man=[Do (not) check for existence of man pages]:boolean:(1 0)' \
    '--order[When generating graph for dot, show only order]' \
    '--require[When generating graph for dot, show only requirement]' \
    '--fuzz=[When printing the tree of the critical chain, print also services, which finished TIMESPAN earlier, than the latest in the branch]:TIMESPAN' \
    '--from-pattern=[When generating a dependency graph, filter only origins]:GLOB' \
    '--to-pattern=[When generating a dependency graph, filter only destinations]:GLOB' \
    {-H+,--host=}'[Operate on remote host]:userathost:_sd_hosts_or_user_at_host' \
    {-M+,--machine=}'[Operate on local container]:machine:_sd_machines' \
    '*::systemd-analyze commands:_systemd-analyze_commands'

cmd: